// Copyright 2025 International Digital Economy Academy
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
//
//     http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.

///|
fn should_prevent_default(code : @inputs.Code) -> Bool {
  match code {
    ArrowUp | ArrowDown | ArrowLeft | ArrowRight | Tab | Space => true
    _ => false
  }
}

///|
pub fn register_key_events(pressed_keys : Set[@inputs.Code]) -> Unit {
  window.add_event_listener("keyup", event => {
    let keyboard_event = event.to_keyboard_event().unwrap()
    let keycode = keyboard_event.code() |> @inputs.Code::from_string
    if keycode is Some(c) {
      if should_prevent_default(c) {
        prevent_default_event(event)
      }
      pressed_keys.remove(c)
    }
  })
  window.add_event_listener("keydown", event => {
    let keyboard_event = event.to_keyboard_event().unwrap()
    if keyboard_event.repeat() {
      return
    }
    note_audio_user_activation()
    let keycode = keyboard_event.code() |> @inputs.Code::from_string
    if keycode is Some(c) {
      if should_prevent_default(c) {
        prevent_default_event(event)
      }
      pressed_keys.add(c)
    }
  })
  window.add_event_listener("blur", _event => pressed_keys.clear())
  document_add_event_listener("visibilitychange", _event => {
    if document_hidden() {
      pressed_keys.clear()
    }
  })
}