///|
fn structural_request(name : String) -> Bool {
  name == "TH" ||
  name == "SH" ||
  name == "SS" ||
  name == "PP" ||
  name == "P" ||
  name == "LP" ||
  name == "TP" ||
  name == "IP" ||
  name == "HP" ||
  name == "RS" ||
  name == "RE" ||
  name == "SY" ||
  name == "YS"
}

///|
fn Parser::request_boundary(self : Parser, name : String, line : Int32) -> Unit {
  if !structural_request(name) {
    return
  }
  if self.pending_tag {
    self.warn(
      "missing-tag", "Structural request interrupts a pending TP term", line,
    )
    self.pending_tag = false
    self.kind = Paragraph
  }
  if self.next_heading is Some(_) {
    self.warn(
      "missing-heading", "Structural request interrupts a pending heading", line,
    )
    self.next_heading = None
  }
  self.one_line_font = None
  if self.literal_mode != "" {
    self.warn(
      "interrupted-literal", "Structural request closes an unclosed literal block",
      line,
    )
    self.flush()
    self.literal_mode = ""
    self.literal_lines = 0
    self.font = self.literal_font
  }
  if name == "SH" || name == "SS" || name == "TH" {
    if self.active_link is Some(_) {
      self.warn(
        "interrupted-link", "Section boundary closes an unclosed link", line,
      )
      self.active_link = None
    }
  }
}