///|
fn Parser::font_request(
  self : Parser,
  name : String,
  args : Array[String],
  line : Int32,
) -> Bool {
  if name == "ft" {
    let arg = if args.is_empty() { "P" } else { args[0] }
    let next = if arg == "P" || arg == "0" {
      Some(self.previous)
    } else {
      font_named(arg)
    }
    match next {
      Some(font) => {
        self.previous = self.font
        self.font = font
      }
      None => self.warn("unknown-font", "Unsupported ft font: " + arg, line)
    }
    return true
  }
  let fonts : Array[Font] = match name {
    "B" | "SB" => [Bold]
    "I" => [Italic]
    "SM" => [Roman]
    "BR" => [Bold, Roman]
    "BI" => [Bold, Italic]
    "IB" => [Italic, Bold]
    "IR" => [Italic, Roman]
    "RB" => [Roman, Bold]
    "RI" => [Roman, Italic]
    _ => return false
  }
  if args.is_empty() {
    self.one_line_font = Some(fonts[0])
    return true
  }
  if self.literal_mode != "" {
    if self.literal_lines > 0 {
      self.retain(Inline::text("\n"), line)
    }
    self.literal_lines = self.literal_lines + 1
  } else if !self.current.is_empty() && !self.continues {
    self.retain(Inline::text(" "), line)
  }
  let saved = self.font
  let previous = self.previous
  if fonts.length() == 1 {
    self.font = fonts[0]
    self.append(joined_arguments(args), line, join=false)
  } else {
    for i = 0; i < args.length(); i = i + 1 {
      self.font = fonts[i % fonts.length()]
      self.append(args[i], line, join=false)
    }
  }
  self.font = saved
  self.previous = previous
  true
}