///|
fn rotr(value : UInt, count : Int) -> UInt {
  (value >> count) | (value << (32 - count))
}

///|
/// SHA-256 of exact input bytes for bundle integrity, not authentication.
pub fn sha256_hex(bytes : Bytes) -> String {
  let constants : Array[UInt] = [
    0x428a2f98, 0x71374491, 0xb5c0fbcf, 0xe9b5dba5, 0x3956c25b, 0x59f111f1, 0x923f82a4,
    0xab1c5ed5, 0xd807aa98, 0x12835b01, 0x243185be, 0x550c7dc3, 0x72be5d74, 0x80deb1fe,
    0x9bdc06a7, 0xc19bf174, 0xe49b69c1, 0xefbe4786, 0x0fc19dc6, 0x240ca1cc, 0x2de92c6f,
    0x4a7484aa, 0x5cb0a9dc, 0x76f988da, 0x983e5152, 0xa831c66d, 0xb00327c8, 0xbf597fc7,
    0xc6e00bf3, 0xd5a79147, 0x06ca6351, 0x14292967, 0x27b70a85, 0x2e1b2138, 0x4d2c6dfc,
    0x53380d13, 0x650a7354, 0x766a0abb, 0x81c2c92e, 0x92722c85, 0xa2bfe8a1, 0xa81a664b,
    0xc24b8b70, 0xc76c51a3, 0xd192e819, 0xd6990624, 0xf40e3585, 0x106aa070, 0x19a4c116,
    0x1e376c08, 0x2748774c, 0x34b0bcb5, 0x391c0cb3, 0x4ed8aa4a, 0x5b9cca4f, 0x682e6ff3,
    0x748f82ee, 0x78a5636f, 0x84c87814, 0x8cc70208, 0x90befffa, 0xa4506ceb, 0xbef9a3f7,
    0xc67178f2,
  ]
  let hash : Array[UInt] = [
    0x6a09e667, 0xbb67ae85, 0x3c6ef372, 0xa54ff53a, 0x510e527f, 0x9b05688c, 0x1f83d9ab,
    0x5be0cd19,
  ]
  let data = bytes.to_array()
  let bits = bytes.length().to_uint64() * 8
  data.push(0x80)
  while data.length() % 64 != 56 {
    data.push(0)
  }
  for i in 0..<8 {
    data.push(((bits >> (56 - i * 8)) & 255).to_byte())
  }
  for block = 0; block < data.length(); block = block + 64 {
    let words : Array[UInt] = Array::make(64, 0)
    for i in 0..<16 {
      let j = block + i * 4
      words[i] = (data[j].to_uint() << 24) |
        (data[j + 1].to_uint() << 16) |
        (data[j + 2].to_uint() << 8) |
        data[j + 3].to_uint()
    }
    for i in 16..<64 {
      let x = words[i - 15]
      let y = words[i - 2]
      words[i] = words[i - 16] +
        (rotr(x, 7) ^ rotr(x, 18) ^ (x >> 3)) +
        words[i - 7] +
        (rotr(y, 17) ^ rotr(y, 19) ^ (y >> 10))
    }
    let state = hash.copy()
    for i in 0..<64 {
      let a = state[0]
      let b = state[1]
      let c = state[2]
      let e = state[4]
      let f = state[5]
      let g = state[6]
      let t1 = state[7] +
        (rotr(e, 6) ^ rotr(e, 11) ^ rotr(e, 25)) +
        ((e & f) ^ (e.lnot() & g)) +
        constants[i] +
        words[i]
      let t2 = (rotr(a, 2) ^ rotr(a, 13) ^ rotr(a, 22)) +
        ((a & b) ^ (a & c) ^ (b & c))
      state[7] = g
      state[6] = f
      state[5] = e
      state[4] = state[3] + t1
      state[3] = c
      state[2] = b
      state[1] = a
      state[0] = t1 + t2
    }
    for i in 0..<8 {
      hash[i] = hash[i] + state[i]
    }
  }
  hash.map(word => word.to_string(radix=16).pad_start(8, '0')).join("")
}