// Copyright 2025 International Digital Economy Academy
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
//
//     http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.

///|
#callsite(autofill(loc))
pub fn t(x : Bool, msg? : String, loc~ : SourceLoc) -> Unit raise {
  if !x {
    let fail_msg = match msg {
      Some(msg) => msg
      None => "`\{x}` is not true"
    }
    fail(fail_msg, loc~)
  }
}

///|
#callsite(autofill(loc))
pub fn f(x : Bool, msg? : String, loc~ : SourceLoc) -> Unit raise {
  if x {
    let fail_msg = match msg {
      Some(msg) => msg
      None => "`\{x}` is not true"
    }
    fail(fail_msg, loc~)
  }
}

///|
fn[T] any_to_string(value : T) -> String = "%any.to_string"

///|
#callsite(autofill(loc))
pub fn[T : Eq] eq(a : T, b : T, msg? : String, loc~ : SourceLoc) -> Unit raise {
  if a != b {
    let fail_msg = match msg {
      Some(msg) => msg
      None => "`\{any_to_string(a)} != \{any_to_string(b)}`"
    }
    fail(fail_msg, loc~)
  }
}

///|
#callsite(autofill(loc))
pub fn[T : Eq] ne(a : T, b : T, msg? : String, loc~ : SourceLoc) -> Unit raise {
  if a == b {
    let fail_msg = match msg {
      Some(msg) => msg
      None => "`\{any_to_string(a)} == \{any_to_string(b)}`"
    }
    fail(fail_msg, loc~)
  }
}

///|
#callsite(autofill(loc))
pub fn raises(f : () -> Unit raise, loc~ : SourceLoc) -> Unit raise {
  try f() catch {
    _ => return
  } noraise {
    _ => fail("Expected function to raise an error", loc~)
  }
}